1119: 访问可能未定义的属性 READY (通过 static 类型 Class 引用)。完全不知道是什么？

import fl.video.*;
var my_FLVPlybk:FLVPlayback = new FLVPlayback();
my_FLVPlybk.source = "1.flv";
my_FLVPlybk.skin="SkinOverAll.swf"
my_FLVPlybk.totalTime = 3600;//总时间
my_FLVPlybk.autoPlay = false;//加载完不会立即播放
my_FLVPlybk.width = 640;
my_FLVPlybk.height = 360;
my_FLVPlybk.x = 0;
my_FLVPlybk.y = 0;
var cuePt:Object = new Object();
cuePt.time = 2.02;//秒
cuePt.name = "pt1";
cuePt.type = "actionscript";
my_FLVPlybk.addASCuePoint(cuePt);
my_FLVPlybk.addASCuePoint(5,"pt2");
my_FLVPlybk.addEventListener(VideoEvent.READY, onFlvPlayback_READY);
function onFlvPlayback_READY(event:VideoEvent):void
{
    trace("onFlvPlayback_READY");
    var tempFlvPlayback:FLVPlayback = event.target as FLVPlayback;
    trace("tempFlvPlayback.source: "+tempFlvPlayback.source);

    var metaDataObj:Object = my_FLVPlybk.metadata as Object;
    trace("metaDataObj.canSeekToEnd: "+metaDataObj.canSeekToEnd);
    trace("metaDataObj.height: "+metaDataObj.height);
    trace("metaDataObj.width: "+metaDataObj.width);
    trace("metaDataObj.duration: "+metaDataObj.duration);
}
my_FLVPlybk.addEventListener(MetadataEvent.CUE_POINT, cp_listener);
function cp_listener(eventObject:MetadataEvent):void{
    trace(my_FLVPlybk.playheadTime);
    trace(eventObject.info.name);
    trace(eventObject.info.type);
}
my_FLVPlybk.addEventListener(Event.COMPLETE, complete_listener);//播放完成时
function complete_listener(event:Event):void{
    if (my_FLVPlybk.source == "1flv"){
        my_FLVPlybk.play("2.flv");
    }
}
addChild(my_FLVPlybk);

---

因为冲突
fl.video.VideoEvent
flash.events.VideoEvent

所以要明确的写出
function onFlvPlayback_READY(event:fl.video.VideoEvent):void
my_FLVPlybk.addEventListener(fl.video.VideoEvent.READY, onFlvPlayback_READY);